Elenarie's Installer

What is this?

-This is a simple project intended to replace the game's current installer with a much better one.
-It should be attractive to people who keep installers on their systems or storage devices.
-It features a much better compression than the game's current installer, resulting in a smaller file size (415 MBs compared to GOG's 476MBs).
-It installs the DirectX and VisualC++ prerequisites silently.
-It offers the ability to create Desktop, Quick Launch, and Start shortcuts.
-It offers the ability to delete the configuration and save data after uninstalling the game.
-It is compatible with Windows XP, Windows Vista, Windows 7, and Windows 8.

Where to get it from?

Look at the second post.

How to compile it?

-Install the game using the game's current installer.
-Install Inno Setup 5.5.1 Unicode or a newer version.
-Create a folder on your desktop. Name it Legend of Grimrock.
-Create two folders inside the Legend of Grimrock folder. Name the first one Game. Name the second one Prerequisites.
-Create two folders inside the Prerequisites folder. Name the first one DirectX. Name the second one Visual C++.
-Download the DirectX Redistributable Package from: http://www.microsoft.com/en-us/download/details.aspx?id=8109. Run it, and tell it to extract the files into the DirectX folder. 157 files should be extracted.
-Download the Visual C++ Redistributable Package from: http://www.microsoft.com/en-us/download/details.aspx?id=8328. Copy it into the Visual C++ folder.
-Copy these files, from the game's original installation directory, into the Game folder: FreeImage.dll, grimrock.dat, grimrock.exe, and lua51.dll.
-Delete the game using Programs and Features.
-Copy the installation script into the Legend of Grimrock folder. Open the installation script using Inno Setup. Click the Compile button to compile the installer. This process could take 10-30 minutes depending on your system's capabilities.
-After the process is done, you should have a perfectly working installer named Legend of Grimrock in the Legend of Grimrock folder, which you can archive and use to install the game whenever you want to play it.

The whole script for those interested. Just copy paste this into Inno Setup.

[Setup]

AppCopyright="Almost Human"
AppId="{{A5FCBF30-FF27-4011-9952-BE90049A1AB2}"
AppName="Legend of Grimrock"
AppPublisher="Almost Human"
AppVerName="Legend of Grimrock"
AppVersion="1.1.4.0"

AllowNoIcons="yes"
AlwaysShowDirOnReadyPage="yes"
AlwaysShowGroupOnReadyPage="yes"
Compression="lzma2/ultra64"
DefaultDirName="{pf32}\Legend of Grimrock"
DefaultGroupName="Games"
InternalCompressLevel="ultra64"
SolidCompression="yes"

OutputBaseFilename="Legend of Grimrock"
OutputDir="."
UninstallDisplayIcon="{app}\grimrock.exe"
VersionInfoVersion="1.1.4.0"

[Files]

Source: "Game\*"; DestDir: "{app}"; Flags: "ignoreversion";
Source: "Prerequisites\DirectX\*"; DestDir: "{tmp}"; Flags: "deleteafterinstall ignoreversion";
Source: "Prerequisites\Visual C++\*"; DestDir: "{tmp}"; Flags: "deleteafterinstall ignoreversion";

[Icons]

Name: "{group}\Legend of Grimrock"; Filename: "{app}\grimrock.exe"; Comment: "Legend of Grimrock";
Name: "{commondesktop}\Legend of Grimrock"; Filename: "{app}\grimrock.exe"; Comment: "Legend of Grimrock"; Tasks: "DesktopIcon";
Name: "{userappdata}\Microsoft\Internet Explorer\Quick Launch\Legend of Grimrock"; Filename: "{app}\grimrock.exe"; Comment: "Legend of Grimrock"; Tasks: "QuickLaunchIcon";

[Tasks]

Name: "DesktopIcon"; Description: "Create an icon on the Desktop."; Flags: "unchecked";
Name: "QuickLaunchIcon"; Description: "Create an icon in the Quick Launch list."; Flags: "unchecked";

[Code]

procedure CurStepChanged(CurStep: TSetupStep);
var
ResultCode: Integer;
begin
case CurStep of ssPostInstall:
begin
Exec(ExpandConstant('{tmp}\DXSETUP.exe'), '/silent', '', SW_SHOW, ewWaitUntilTerminated, ResultCode);
Exec(ExpandConstant('{tmp}\vcredist_x86.exe'), '/q /norestart', '', SW_SHOW, ewWaitUntilTerminated, ResultCode);
end;
end;
end;

procedure CurUninstallStepChanged(CurUninstallStep: TUninstallStep);
begin
case CurUninstallStep of usPostUninstall:
begin
if DirExists(ExpandConstant('{app}')) or DirExists(ExpandConstant('{userdocs}\Almost Human\Legend of Grimrock')) then
begin
if MsgBox('Do you want to delete all configuration and save data?', mbConfirmation, MB_YESNO) = IDYES then
begin
if DirExists(ExpandConstant('{app}')) then
begin
DelTree(ExpandConstant('{app}'), True, True, True);
end;
if DirExists(ExpandConstant('{userdocs}\Almost Human\Legend of Grimrock')) then
begin
DelTree(ExpandConstant('{userdocs}\Almost Human\Legend of Grimrock'), True, True, True);
RemoveDir(ExpandConstant('{userdocs}\Almost Human'));
end;
end;
end;
end;
end;
end;

Modified the script slightly, just some minor code writing standard, the functionality is all the same.