There is a RamDisk guide on steam discussion of Kenshi (see references below).

For the sake of completeness I will post the GOG Galaxy version of that guide here.

0. prerequisites
- 16GB (32GB?) or more RAM; Kenshi game files totals to about 12GB
- windows operating system
- command prompt with admin privileges
- ImDisk; virtual disk driver; http://www.ltr-data.se/opencode.html/#ImDisk

1. after ImDisk is installed, execute commands below in the command prompt as administrator
#+begin_src bat
:: Set variables for convenience
SET KENSHIINSTALLDISK=C:
SET KENSHIRAMDISK=K:
SET "KENSHIINSTALLDIR=%KENSHIINSTALLDISK%\Program Files (x86)\GOG Galaxy\Games\Kenshi"
SET "KENSHIRAMDIR=%KENSHIRAMDISK%\Program Files (x86)\GOG Galaxy\Games\Kenshi"

:: Create a virtual disk drive (K:\)
::
:: IMDISK => download and install from
:: http://www.ltr-data.se/opencode.html/#ImDisk
:: -a => Attach a virtual disk, this will create the K:\ disk letter
:: -s => Specify the size of the virtual disk
:: -m => Specify which letter to use
:: -p => Specify the filesystem and other format parameters
IMDISK -a -s 12G -m %KENSHIRAMDISK% -p "/fs:ntfs /q /y"

:: Create a directory tree in the virtual disk
::
:: MD => Make Directory
MD "%KENSHIRAMDIR%"

:: Link the save file from HDD/SSD to the virtual disk,
:: so that the save files will persist after shutdown/reboot
::
:: MKLINK => Make Link => Create a symbolic link
:: /d => Create a directory symbolic link
MKLINK /d "%KENSHIRAMDIR%\save" "%KENSHIINSTALLDIR%\save"

:: Copy the game files from HDD/SSD to the virtual disk
::
:: Robust file copy for windows, like cp in linux
:: /E => copy subdirectories, including empty ones
:: /XD => eXclude Directories matching given names/paths
:: this will prevent the /save directory from being synced
ROBOCOPY "%KENSHIINSTALLDIR%" "%KENSHIRAMDIR%" /E /XD "%KENSHIINSTALLDIR%\save"
#+end_src

2. point gog kenshi to the virtual disk executable
- Open GOG Galaxy
- Open "Manage installation" (either right click Kenshi in the installed games list, or click Kenshi and click the Settings icon)
- Click "Configure..."
- Click "FEATURES" tab
- Click "Add another executable / arguments"
- Select "K:\Program Files (x86)\GOG Galaxy\Games\Kenshi\kenshi_GOG_x64.exe"
- Click "Default executable" radio button
- Click "OK" button
- ???
- Profit! (start playing as usual)

3. after starting the game, confirm that Kenshi is using the virtual disk
- Open "Task Manager"
- Click "Processes" tab
- Right click "Name" column
- Click "Command line"; this will show another column
- See that in the process named "kenshi_GOG_x64.exe", the value of the "Command line" starts with "K:\..." instead of "C:\..."

4. to return back to playing with the HDD/SSD instead of the virtual disk,
- Open "Manage installation" (either right click Kenshi in the installed games list, or click the Settings icon)
- Click "Configure..."
- Click "FEATURES" tab
- Click "Default executable" radio button of "File 1"
- Click "OK" button
- ???
- Profit! (start playing as usual)

5. CAVEAT
- since RAM is non-persistent memory, the commands in step#1 need to be executed again every time the computer is rebooted
- it is possible to run the commands in step#1 automatically at startup. this is left as an exercise to the reader
(HINT https://www.google.com/search?q=windows+start+batch+script+on+startup)

6. references
- https://steamcommunity.com/app/233860/discussions/2/152390648085459659/
- https://www.lofigames.com/phpBB3/viewtopic.php?f=5&t=7510